How to Scroll Up/Down Left/Right with Your NaviFut Foot Mouse (Windows)

The xStep works as a standard plug-and-play mouse out of the box. But with a free tool called AutoHotkey, you can unlock an extra feature: a scroll mode that lets you scroll any page or document just by moving your foot — no hands needed.

This guide walks you through the full setup on Windows.

What You’ll Need

A Windows PC and about 5 minutes.

Step 1 — Download AutoHotkey

Go to https://www.autohotkey.com/download/1.1/ and click Download. Make sure you download version 1.1. Do not download version 2, the script will not work with it.

Run the installer and follow the default steps.

Step 2 — Create the Script File

Open Notepad (search for it in the Windows start menu).

Copy and paste the following script into Notepad:

#NoEnv
#SingleInstance Force
SendMode Input

; Variables
scrollMode := false
lastRClick := 0

RButton::
    currentTime := A_TickCount
    timeDiff := currentTime - lastRClick

    if (scrollMode)
    {
        scrollMode := false
        ToolTip, Scroll Mode OFF
        SetTimer, RemoveToolTip, -1000
        SetTimer, DoScroll, Off
        lastRClick := 0
        return
    }

    if (timeDiff < 1500) ; <-- Maximum delay in ms between the two clicks to activate scroll mode. Increase if too fast, decrease if too sensitive
    {
        Send, {Escape}
        scrollMode := true
        ToolTip, Scroll Mode ON
        SetTimer, RemoveToolTip, -1000
        SetTimer, DoScroll, 20
        lastRClick := 0
    }
    else
    {
        lastRClick := currentTime
        Send, {RButton}
    }
return

LButton::
    if (scrollMode)
    {
        scrollMode := false
        ToolTip, Scroll Mode OFF
        SetTimer, RemoveToolTip, -1000
        SetTimer, DoScroll, Off
    }
    else
        Send, {LButton}
return

DoScroll:
    if (!scrollMode)
    {
        SetTimer, DoScroll, Off
        return
    }
    MouseGetPos, mouseX, mouseY

    deltaX := mouseX - lastX
    deltaY := mouseY - lastY

     if (Abs(deltaY) > 5) ; <-- adjust this number to modify scroll speed
        Send, % (deltaY > 0) ? "{WheelDown}" : "{WheelUp}"
    if (Abs(deltaX) > 5) ; <-- adjust this number to modify scroll speed
        Send, % (deltaX > 0) ? "{WheelRight}" : "{WheelLeft}"

    lastX := mouseX
    lastY := mouseY
return

RemoveToolTip:
    ToolTip
return

Now save the file. Click File → Save As. At the bottom of the save dialog, change “Save as type” to All Files. Name the file NaviFut_scroll_mode.ahk and save it somewhere easy to find, like your Desktop.

Step 3 — Run the Script

Double-click the scroll_mode.ahk file. A small green icon will appear in your system tray (bottom right of your taskbar). That means the script is running.

Step 4 — How to Use Scroll Mode

• Double right-click with the xStep to activate scroll mode. A small tooltip will confirm “Scroll Mode ON”
• Move your foot to scroll – forward/backward scrolls up and down, left/right scrolls laterally
• Any single left or right click exits scroll mode and returns to normal cursor control

How to Stop the Script

Right-click the green icon in the system tray and select Exit. Your mouse will return to normal behaviour immediately.

How to Make It Start Automatically with Windows

If you want the script to run every time you start your PC, press Windows + R, type shell:startup and press Enter. Copy your scroll_mode.ahk file into the folder that opens. That’s it.

Troubleshooting

The double-click isn’t triggering scroll mode. The default window between the two clicks is 1500ms. If you find it too sensitive or not sensitive enough, open the script in Notepad, find the line that says if (timeDiff < 1500) and change the number to suit your preference.

The context menu doesn’t close when scroll mode activates. This can happen in some applications. It doesn’t affect scroll mode itself – just close it manually and continue scrolling.

The script stopped working after a Windows update. Just double-click the .ahk file again to restart it.

Mac and Linux versions of this guide are coming soon. If you need help setting up button remapping or custom scripts on any platform, feel free to reach out via our contact page.